M7350v1_en_gpl

oe-core/meta-demoapps/recipes-gnome/abiword/abiword-2.5.inc

@@ -0,0 +1,64 @@
+DESCRIPTION = "AbiWord is free word processing program similar to Microsoft(r) Word"
+HOMEPAGE = "http://www.abiword.org"
+SECTION = "x11/office"
+LICENSE = "GPLv2"
+DEPENDS     = "perl-native wv libgsf libglade libfribidi jpeg libpng libxml2"
+RDEPENDS_${PN}    = "glibc-gconv-ibm850 glibc-gconv-cp1252 \
+               glibc-gconv-iso8859-15 glibc-gconv-iso8859-1"
+
+SRC_URI = "http://www.abiword.org/downloads/abiword/${PV}/source/abiword-${PV}.tar.gz"
+
+#want 2.x from 2.x.y for the installation directory
+SHRT_VER = "${@d.getVar('PV',1).split('.')[0]}.${@d.getVar('PV',1).split('.')[1]}"
+
+FILES_${PN} += " \
+		${datadir}/icons/* \
+		${datadir}/abiword-${SHRT_VER}/glade \
+		${datadir}/abiword-${SHRT_VER}/scripts \
+		${datadir}/abiword-${SHRT_VER}/system.profile-en \
+		${datadir}/abiword-${SHRT_VER}/system.profile-en_GB \
+		${datadir}/abiword-${SHRT_VER}/templates/normal.awt \
+		${datadir}/abiword-${SHRT_VER}/templates/normal.awt-en_GB \
+		${datadir}/abiword-${SHRT_VER}/templates/Employee-Directory.awt \
+		${datadir}/abiword-${SHRT_VER}/templates/Business-Report.awt \
+		${datadir}/abiword-${SHRT_VER}/templates/Fax-Coversheet.awt \
+		${datadir}/abiword-${SHRT_VER}/templates/Resume.awt \
+		${datadir}/abiword-${SHRT_VER}/templates/Two-Columns.awt \
+		${datadir}/abiword-${SHRT_VER}/templates/Memo.awt \
+		${datadir}/abiword-${SHRT_VER}/templates/Press-Release.awt "
+
+#		${datadir}/abiword-${SHRT_VER}/templates/A4.awt \
+#		${datadir}/abiword-${SHRT_VER}/templates/US-Letter.awt \
+
+inherit autotools pkgconfig
+
+PARALLEL_MAKE = ""
+
+EXTRA_OECONF = " --disable-pspell \
+                 --disable-spellcheck \
+		 --disable-printing \
+		 --disable-exports \
+		 --with-sys-wv"
+
+# AbiWord configure.ac does not play nicely with autoreconf
+# so use the autogen.sh script that comes with AbiWord
+#
+do_configure() {
+        cd ${S}
+        export NOCONFIGURE="no"; ./autogen.sh
+        oe_runconf
+}
+
+
+do_install_append() {
+        install -d ${D}${datadir}/pixmaps/
+        mv ${D}${datadir}/icons/* ${D}${datadir}/pixmaps/
+}
+
+PACKAGES += " abiword-clipart abiword-icons abiword-strings abiword-systemprofiles abiword-templates "
+
+FILES_abiword-clipart 		+= "${datadir}/abiword-${SHRT_VER}/clipart"
+FILES_abiword-icons 		+= "${datadir}/abiword-${SHRT_VER}/icons"
+FILES_abiword-strings 		+= "${datadir}/abiword-${SHRT_VER}/AbiWord/strings"
+FILES_abiword-systemprofiles 	+= "${datadir}/abiword-${SHRT_VER}/AbiWord/system.profile*"
+FILES_abiword-templates 	+= "${datadir}/abiword-${SHRT_VER}/templates"

oe-core/meta-demoapps/recipes-gnome/abiword/abiword-embedded_2.5.2.bb

@@ -0,0 +1,12 @@
+require abiword-2.5.inc
+
+PR = "r1"
+
+EXTRA_OECONF += "--enable-embedded"
+
+S = "${WORKDIR}/abiword-${PV}"
+
+RCONFLICTS = "abiword"
+RPROVIDES += "abiword"
+
+

oe-core/meta-demoapps/recipes-gnome/abiword/abiword.inc

@@ -0,0 +1,64 @@
+DESCRIPTION = "AbiWord is free word processing program similar to Microsoft(r) Word"
+SECTION = "gnome/office"
+HOMEPAGE = "http://www.abiword.org""
+LICENSE = "GPLv2"
+
+DEPENDS     = "libgsf libglade libfribidi libxml2 wv"
+RRECOMMENDS_${PN}    = "glibc-gconv-ibm850 glibc-gconv-cp1252 \
+               glibc-gconv-iso8859-15 glibc-gconv-iso8859-1"
+
+# Share this file between recipes that use cvs and that pull tarballs
+# (one day change this to differentiate automatically based on PV and set the
+# SRC_URI and S var directly)
+RELURI = "http://www.abiword.org/downloads/abiword/${PV}/source/abiword-${PV}.tar.gz"
+RELSRC = "${WORKDIR}/abiword-${PV}/abi"
+
+SVNURI = "svn://svn.abisource.com/abiword/trunk;module=abiword;proto=http"
+SVNSRC = "${WORKDIR}/abi"
+
+#want 2.x from 2.x.y for the installation directory
+SHRT_VER = "${@d.getVar('PV',1).split('.')[0]}.${@d.getVar('PV',1).split('.')[1]}"
+
+FILES_${PN} += " \
+		${datadir}/icons/* \
+		${datadir}/mime-info \
+		${datadir}/abiword-${SHRT_VER}/glade \
+		${datadir}/abiword-${SHRT_VER}/system.profile-en \
+		${datadir}/abiword-${SHRT_VER}/system.profile-en-GB \
+  "
+
+#		${datadir}/abiword-${SHRT_VER}/templates/normal.awt \
+#		${datadir}/abiword-${SHRT_VER}/templates/normal.awt-en_GB \
+
+inherit autotools pkgconfig
+
+PARALLEL_MAKE = ""
+
+# This is a minimalistic AbiWord build
+#
+# if you are planning to build plugins, make sure to comment out the
+# --disable-exports options
+
+EXTRA_OECONF = " --enable-embedded=poky    \
+		 --disable-printing   \
+		 --with-sys-wv 	     \
+		 --disable-exports    \
+		 --disable-spellcheck"
+
+# TODO -- refactor this, so that instead of two strings and profiles
+# packages we have lots of locale packages, each with a set of strings and
+# a profile
+#
+PACKAGES += " abiword-strings abiword-systemprofiles"
+
+FILES_abiword-strings 		+= "${datadir}/abiword-${SHRT_VER}/strings"
+FILES_abiword-systemprofiles 	+= "${datadir}/abiword-${SHRT_VER}/system.profile*"
+
+# AbiWord configure.ac does not play nicely with autoreconf
+# so use the autogen.sh script that comes with AbiWord
+#
+do_configure() {
+	cd ${S}
+	export NOCONFIGURE="no"; ./autogen.sh
+	oe_runconf
+}

oe-core/meta-demoapps/recipes-gnome/abiword/abiword_2.5.2.bb

@@ -0,0 +1,5 @@
+require abiword-2.5.inc
+
+PR = "r2"
+
+RCONFLICTS_${PN} = "abiword-embedded"

oe-core/meta-demoapps/recipes-gnome/abiword/abiword_svn.bb

@@ -0,0 +1,10 @@
+require abiword.inc
+
+SRCREV = "21818"
+PV="2.5.2+svnr${SRCPV}"
+PR = "r0"
+
+SRC_URI = "${SVNURI}"
+
+S = "${SVNSRC}"
+