M7350v1_en_gpl

oe-core/meta/recipes-kernel/linux-libc-headers/linux-libc-headers-yocto_git.bb

@@ -0,0 +1,55 @@
+require linux-libc-headers.inc
+include recipes-kernel/linux/linux-yocto.inc
+
+B = "${S}"
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"
+PROVIDES = "linux-libc-headers"
+RPROVIDES_${PN}-dev = "linux-libc-headers-dev"
+RPROVIDES_${PN}-dbg = "linux-libc-headers-dbg"
+SRCREV = "69cfbdf9f1ff461a75e5b77d6d7ba35e97db4cc3"
+PV = "2.6.37+git-${SRCPV}"
+PR = "r4"
+
+SRCREV_FORMAT = "meta_machine"
+SRC_URI = "git://git.yoctoproject.org/linux-yocto-2.6.37;protocol=git;nocheckout=1;branch=${KBRANCH},meta;name=machine,meta"
+
+# force this to empty to prevent installation failures, we aren't
+# building a device tree as part of kern headers
+KERNEL_DEVICETREE=
+
+set_arch() {
+	case ${TARGET_ARCH} in
+		arm*)     ARCH=arm ;;
+		i*86*)    ARCH=i386 ;;
+		ia64*)    ARCH=ia64 ;;
+		mips*)    ARCH=mips ;;
+		powerpc*) ARCH=powerpc ;;
+		x86_64*)  ARCH=x86_64 ;;
+	esac
+}
+
+do_configure() {
+	set_arch
+	oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_kernel_configme() {
+}
+
+do_patch () {
+}
+
+do_compile () {
+}
+
+do_install() {
+	set_arch
+	oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+
+        # The ..install.cmd conflicts between various configure runs
+        find ${D}${includedir} -name ..install.cmd | xargs rm -f
+}
+
+BBCLASSEXTEND = "nativesdk"

oe-core/meta/recipes-kernel/linux-libc-headers/linux-libc-headers.inc

@@ -0,0 +1,66 @@
+DESCRIPTION = "Sanitized set of kernel headers for the C library's use."
+SECTION = "devel"
+LICENSE = "GPLv2"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+
+python __anonymous () {
+    major = d.getVar("PV",True).split('.')[0]
+    if major == "3":
+	d.setVar("HEADER_FETCH_VER", "3.0")
+    else:
+	d.setVar("HEADER_FETCH_VER", "2.6")
+}
+
+SRC_URI = "${KERNELORG_MIRROR}/linux/kernel/v${HEADER_FETCH_VER}/linux-${PV}.tar.bz2"
+
+S = "${WORKDIR}/linux-${PV}"
+
+set_arch() {
+	case ${TARGET_ARCH} in
+		alpha*)   ARCH=alpha ;;
+		arm*)     ARCH=arm ;;
+		cris*)    ARCH=cris ;;
+		hppa*)    ARCH=parisc ;;
+		i*86*)    ARCH=i386 ;;
+		ia64*)    ARCH=ia64 ;;
+		mips*)    ARCH=mips ;;
+		m68k*)    ARCH=m68k ;;
+		powerpc*) ARCH=powerpc ;;
+		s390*)    ARCH=s390 ;;
+		sh*)      ARCH=sh ;;
+		sparc64*) ARCH=sparc64 ;;
+		sparc*)   ARCH=sparc ;;
+		x86_64*)  ARCH=x86_64 ;;
+		avr32*)   ARCH=avr32 ;;
+		bfin*)    ARCH=blackfin ;;
+		microblaze*) ARCH=microblaze ;;
+	esac
+}
+
+do_configure() {
+	set_arch
+	oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_compile () {
+}
+
+do_install() {
+	set_arch
+	oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+	# Kernel should not be exporting this header
+	rm -f ${D}${exec_prefix}/include/scsi/scsi.h
+
+	# The ..install.cmd conflicts between various configure runs
+	find ${D}${includedir} -name ..install.cmd | xargs rm -f
+}
+
+BBCLASSEXTEND = "nativesdk"
+
+#DEPENDS = "cross-linkage"
+RDEPENDS_${PN}-dev = ""
+RRECOMMENDS_${PN}-dbg = "${PN}-dev (= ${EXTENDPKGV})"
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"

oe-core/meta/recipes-kernel/linux-libc-headers/linux-libc-headers/connector-msg-size-fix.patch

@@ -0,0 +1,29 @@
+Upstream-Status: Inappropriate [embedded specific]
+
+Currently default header is linux-libc-header, which leads the dismatch
+with wrs kernel.
+
+The different headers for same file cause trouble between kerenl module and
+user level binary. E.g. segfault in v86d due to different
+CONNECTOR_MAX_MSG_SIZE in connector.h from the one used by uvesafb.
+
+This fix is work around to sync with wrs kernel headers, and should be removed
+after switching to linux-libc-headers-wrs.
+
+[BUGID #279] fixed by this.
+
+Signed-off-by: Zhai Edwin <edwin.zhai@intel.com>
+
+Index: linux-2.6.34/include/linux/connector.h
+===================================================================
+--- linux-2.6.34.orig/include/linux/connector.h	2010-09-30 14:15:25.000000000 +0800
++++ linux-2.6.34/include/linux/connector.h	2010-09-30 14:15:43.000000000 +0800
+@@ -48,7 +48,7 @@
+ /*
+  * Maximum connector's message size.
+  */
+-#define CONNECTOR_MAX_MSG_SIZE		16384
++#define CONNECTOR_MAX_MSG_SIZE		65536
+ 
+ /*
+  * idx and val are unique identifiers which 

oe-core/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_3.0.8.bb

@@ -0,0 +1,7 @@
+require linux-libc-headers.inc
+
+PR = "r1"
+
+SRC_URI += " file://connector-msg-size-fix.patch"
+SRC_URI[md5sum] = "eac4d398a0ecd98214487cd47a228998"
+SRC_URI[sha256sum] = "4ed16da319848f681f711dbda2ac2cf1b306a280ec22f90bae190cf23b533add"

oe-core/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_3.1.bb

@@ -0,0 +1,7 @@
+require linux-libc-headers.inc
+
+PR = "r1"
+
+SRC_URI += " file://connector-msg-size-fix.patch"
+SRC_URI[md5sum] = "8d43453f8159b2332ad410b19d86a931"
+SRC_URI[sha256sum] = "2573d2378c754b0c602b57586e9311e5b38c5d1e6c137f02873833633a4b9359"