M7350v1_en_gpl

oe-core/meta/recipes-devtools/syslinux/files/cross-build.patch

@@ -0,0 +1,71 @@
+Upstream-Status: Inappropriate [configuration]
+
+Use ?= for Makefile variables to use poky environment variables.
+Original method to sed s/CC =/CC ?=/ is not applicable anymore
+because of the Makefile changes.
+
+against 3.86
+
+06/28/2010 - qhe
+
+also AUXDIR stays in $(LIBDIR)/syslinux rather than $(DATADIR)/syslinux
+
+07/08/2010 - qhe
+
+updated for 4.03
+
+11/16/2010 - Qing He <qing.he@intel.com>
+
+---
+diff --git a/MCONFIG b/MCONFIG
+index e9c16d3..4d49f33 100644
+--- a/MCONFIG
++++ b/MCONFIG
+@@ -18,13 +18,13 @@
+ MAKEFLAGS += -r
+ MAKE      += -r
+ 
+-BINDIR   = /usr/bin
+-SBINDIR  = /sbin
+-LIBDIR   = /usr/lib
+-DATADIR  = /usr/share
+-AUXDIR   = $(DATADIR)/syslinux
+-MANDIR	 = /usr/man
+-INCDIR   = /usr/include
++BINDIR   ?= /usr/bin
++SBINDIR  ?= /sbin
++LIBDIR   ?= /usr/lib
++DATADIR  ?= /usr/share
++AUXDIR   = $(LIBDIR)/syslinux
++MANDIR	 ?= /usr/man
++INCDIR   ?= /usr/include
+ TFTPBOOT = /tftpboot
+ COM32DIR = $(AUXDIR)/com32
+ 
+@@ -38,18 +38,18 @@ PERL	 = perl
+ 
+ CHMOD	 = chmod
+ 
+-CC	 = gcc
++CC	 ?= gcc
+ gcc_ok   = $(shell tmpf=gcc_ok.$$$$.tmp; \
+ 		   if $(CC) $(GCCOPT) $(1) -c $(topdir)/dummy.c \
+ 			-o $$tmpf 2>/dev/null ; \
+ 		   then echo '$(1)'; else echo '$(2)'; fi; \
+ 		   rm -f $$tmpf)
+ 
+-LD	 = ld
+-OBJDUMP	 = objdump
+-OBJCOPY  = objcopy
+-AR       = ar
+-NM       = nm
+-RANLIB   = ranlib
++LD	 ?= ld
++OBJDUMP	 ?= objdump
++OBJCOPY  ?= objcopy
++AR       ?= ar
++NM       ?= nm
++RANLIB   ?= ranlib
+ GZIPPROG = gzip
+ PNGTOPNM = pngtopnm
+ MCOPY    = mcopy

oe-core/meta/recipes-devtools/syslinux/syslinux_4.03.bb

@@ -0,0 +1,62 @@
+DESCRIPTION = "A multi-purpose linux bootloader"
+HOMEPAGE = "http://syslinux.zytor.com/"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+                    file://README;beginline=28;endline=34;md5=a4607efd4a6392017186d08099e7d546"
+
+# If you really want to run syslinux, you need mtools.  We just want the
+# ldlinux.* stuff for now, so skip mtools-native
+DEPENDS = "nasm-native"
+PR = "r4"
+
+SRC_URI = "${KERNELORG_MIRROR}/linux/utils/boot/syslinux/4.xx/syslinux-${PV}.tar.bz2 \
+           file://cross-build.patch"
+
+SRC_URI[md5sum] = "a7ca38a0a5786b6efae8fb01a1ae8070"
+SRC_URI[sha256sum] = "c65567e324f9d1f7f794ae8f9578a0292bbd47d7b8d895a004d2f0152d0bda38"
+
+COMPATIBLE_HOST = '(x86_64|i.86).*-(linux|freebsd.*)'
+
+EXTRA_OEMAKE = " \
+	BINDIR=${bindir} SBINDIR=${sbindir} LIBDIR=${libdir} \
+	DATADIR=${datadir} MANDIR=${mandir} INCDIR=${includedir} \
+"
+# syslinux uses $LD for linking, strip `-Wl,' so it can work
+export LDFLAGS = "`echo $LDFLAGS | sed 's/-Wl,//g'`"
+
+do_configure() {
+	# drop win32 targets or build fails
+	sed -e 's,win32/\S*,,g' -i Makefile
+
+	# clean installer executables included in source tarball
+	oe_runmake clean
+}
+
+do_compile() {
+	# Rebuild only the installer; keep precompiled bootloaders
+	# as per author's request (doc/distrib.txt)
+	oe_runmake CC="${CC}" installer
+}
+
+do_install() {
+	oe_runmake install INSTALLROOT="${D}"
+
+	install -d ${D}${libdir}/syslinux/
+	install -m 644 ${S}/core/ldlinux.sys ${D}${libdir}/syslinux/
+	install -m 644 ${S}/core/ldlinux.bss ${D}${libdir}/syslinux/
+}
+
+PACKAGES =+ "${PN}-extlinux ${PN}-mbr ${PN}-chain ${PN}-pxelinux ${PN}-isolinux"
+
+RDEPENDS_${PN} += "mtools"
+
+FILES_${PN} = "${bindir}/syslinux"
+FILES_${PN}-extlinux = "${sbindir}/extlinux"
+FILES_${PN}-mbr = "${libdir}/${PN}/mbr.bin"
+FILES_${PN}-chain = "${libdir}/${PN}/chain.c32"
+FILES_${PN}-isolinux = "${libdir}/${PN}/isolinux.bin"
+FILES_${PN}-pxelinux = "${libdir}/${PN}/pxelinux.0"
+FILES_${PN}-dev += "${datadir}/${PN}/com32/lib*${SOLIBS} ${datadir}/${PN}/com32/include ${datadir}/${PN}/com32/com32.ld"
+FILES_${PN}-staticdev += "${datadir}/${PN}/com32/lib*.a"
+
+BBCLASSEXTEND = "native"